Denial

Code: Select all

SCREEN_START = $1E00
COLOR_START = $9600
CHARACTER_ROM = $8000
CHARACTER_RAM = $1C00

SCREEN_PAGE = $288
SCREEN_ADDRESS = $FD
COLOR_ADDRESS = $FB

	.org $1001

	; BASIC program to boot the machine language code
	.byte $0B, $10, $0a, $00, $9e, $34, $31, $30, $39, $00, $00, $00
	
	; store the screen address in zero page, for indirect-indexed addressing
	LDA #$00
	STA SCREEN_ADDRESS
	LDA SCREEN_PAGE
	STA SCREEN_ADDRESS + 1

	; lower the top of basic programming
	LDA #$1C
	STA $34
	STA $38
	
	;copy 512 bytes from 32768 $8000 to 7168 $1C00
	ldx #$00
copyChracters:
	LDA CHARACTER_ROM, X
	STA CHARACTER_RAM, X
	LDA CHARACTER_ROM + 256, X
	STA CHARACTER_RAM + 256, X
	INX
	BNE copyChracters	; incrementing past FF will set it back to zero
	
	LDX #$07
makeSmiley:
	LDA smiley, X
	STA CHARACTER_RAM, X
	DEX
	BPL makeSmiley
	
switchToRamSet;
	LDA #$FF
	STA $9005

	LDY #$3F
writeCharacters:
	TYA
	STA (SCREEN_ADDRESS), Y
	LDA #$00
	STA COLOR_START, Y
	DEY
	BPL writeCharacters

done:
	RTS

smiley:
	.byte 	%00111100
	.byte 	%01000010
	.byte 	%10100101
	.byte 	%10000001
	.byte 	%10100101
	.byte 	%10011001
	.byte 	%01000010
	.byte 	%00111100

Code: Select all

// This basic line works for relocatable BASIC programs.
// The .sys_addr will be called relative to the start of the BASIC program.
macro basic_line_20(.line_number, .sys_addr)
{
.start:
	define word = .line2
	define word = .line_number
	define byte[] = {
		// syspeek(43)+256*peek(44)+OFFSET
		$9e, $c2, $28, $34, $33, $29, $aa, $32, $35, $36,
		$ac, $c2, $28, $34, $34, $29, $aa, string(.sys_addr - .start), $00
	}
	define word .line2 = 0
}

Code: Select all

	basic_line_20(2022, start)
start:
	<my program...>

Code: Select all

SCREEN_START	= $1E00
COLOR_START		= $9600
CHARACTER_ROM	= $8000
CHARACTER_RAM	= $1C00

SCREEN_PAGE		= $288
SCREEN_ADDRESS	= $FD
COLOR_ADDRESS	= $FB

START_OF_BASIC	= $2B

FILENAME_Y		= $1C ; 29 bytes past the start of basic

	.org $1001

bootstrap:
	; BASIC program to bootstrap the machine language code
	; 10 sys peek(43) * 256 * peek(44) + 40
	.byte $1A, $04, $0A, $00,  $9E, $20, $C2, $28
	.byte $34, $33, $29, $AC,  $32, $35, $36, $AC
	.byte $C2, $28, $34, $34,  $29, $AA, $34, $30	; $34, $30 ==> skip 40 bytes, 29 bytes for the bootstrap + 11 bytes for the filename
	.byte $00, $00, $00, $00
	
	; declare some data space here. 
	; This address can be found by adding start of basic, stored at $2B $2C, and adding 29 bytes, the length of the boot strap
filename:
	;     H    E    L    L    O    W    O    R    L    D
	.byte $08, $05, $0C, $0C, $0F, $17, $0F, $12, $0C, $04, $00	; 11 bytes

start:
	; store the screen address in zero page, for indirect-indexed addressing
	LDA #$00
	STA SCREEN_ADDRESS
	STA COLOR_ADDRESS
	LDA SCREEN_PAGE
	STA SCREEN_ADDRESS + 1
	; convert screen address to color address
	AND #$03	
	ORA #$94
	STA COLOR_ADDRESS + 1

	; prepare to write the filename to screen by getting the first character and preparing the stack
	LDY #FILENAME_Y				; Set filename index
	TYA
	PHA							; Push filename index on stack
	LDA (START_OF_BASIC), Y		; Load first character into A
	TAX							; Save it in X
	
	LDY #$00					; Set screen index
	TYA
	PHA							; Push screen index on stack

writeCharacters:
	PLA
	TAY							; Pull screen index off stack
	
	TXA							; Put the character back into A

	STA (SCREEN_ADDRESS), Y		; write the character to the screen
	LDA #$00
	STA (COLOR_ADDRESS), Y		; change character to black
	
	INY							; increment the screen index
	TYA
	TAX							; Save it in X

	PLA
	TAY							; Pull the filename index off the stack
	INY							; increment the filename index Y
	
	TYA
	PHA							; Push filename index on stack

	TXA
	PHA							; Push Screen index on Stack

	LDA (START_OF_BASIC), Y		; Load next character
	TAX							; Save it in X
	BNE writeCharacters 		; if it's zero, we're done

	PLA
	PLA							; clean the stack

done:
	RTS